Nichoir connecté

Un nichoir à mésange charbonnière avec une caméra à l’intérieur. On l’alimente depuis le pied de l’arbre quand on veut regarder, on se connecte à son propre réseau WiFi avec un QR code, et l’image arrive sur le téléphone. Fabriqué par un groupe d’enfants, de la découpe des planches au montage électronique.

Le besoin de départ

Un nichoir ne montre rien. C’est même tout son intérêt : une boîte fermée, un trou étroit, la pénombre ; c’est ce qui décide une mésange à s’y installer. Mais pour qui vient de le fabriquer, l’objet s’arrête précisément au moment où il devient intéressant.

Et il n’y a pas de moyen honnête de tricher. Ouvrir un nichoir occupé fait fuir la couvée ; s’approcher trop souvent suffit à décourager les allers-retours des parents. L’observation directe détruit ce qu’elle veut observer.

Le besoin tenait donc en trois contraintes tenues ensemble : voir l’intérieur sans jamais ouvrir, avec du matériel qu’un groupe d’enfants puisse assembler lui-même, et sans rien qui demande un compte, un abonnement ou une box internet au pied de l’arbre.

Comment ça marche

Trois parties : la caisse, la caméra, et l’alimentation qui vient du sol.

L’électronique est figurée à l’extérieur pour la lisibilité. Dans le nichoir, elle est en haut de la caisse et braquée vers le fond ; le câble, lui, descend bien jusqu’au pied de l’arbre.

La caisse est un nichoir ordinaire, aux dimensions de la mésange charbonnière ; c’est le trou d’envol qui décide de l’espèce qui s’installe. Les planches sont découpées sur plan, puis gravées au laser par ceux qui les montent.

La caméra est une carte ESP32-CAM logée dans un boîtier imprimé en 3D, fixée en haut de la caisse et braquée vers le fond. Une LED infrarouge de 850 nm l’éclaire : la longueur d’onde est invisible pour l’œil, donc l’intérieur reste noir pour l’oiseau alors que le capteur, lui, voit.

La carte fabrique son propre réseau WiFi, ouvert, nommé Nichoir. Il n’y a pas de routeur, pas d’internet, pas de compte : le téléphone se connecte directement au nichoir via un QR code affiché au pied de l’arbre, et une petite page propose au choix une photo instantanée ou un flux vidéo. Rien ne sort du parc, rien n’est enregistré.

L’alimentation est le point le moins visible et le plus déterminant. Il n’y a aucune batterie dans l’arbre : on branche une batterie externe en bas, quand on veut regarder. Mais cinq mètres de câble font chuter la tension, et une ESP32-CAM sous-alimentée redémarre en boucle. D’où le montage en deux étages : la tension est montée à 9 V en bas pour encaisser la perte du trajet, puis redescendue à 5,1 V en haut, juste avant la carte. Un condensateur placé au plus près absorbe les pointes de courant du WiFi, qui sont ce qui fait décrocher la carte.

Conséquence de ce choix : hors des moments d’observation, le nichoir redevient un nichoir. Pas de batterie à changer en haut de l’échelle, pas d’électronique qui chauffe en permanence à côté d’une couvée.

Comment c’est fabriqué

Machines

graveuse laser, imprimante 3D

Matériaux

planches de bois prédécoupées, ESP32-CAM-MB, LED infrarouge 850 nm, PLA

Temps

quatre séances sur deux journées

Coût

140 €

Le flanc gravé au laser : des papillons, et les prénoms de ceux qui l’ont monté. C’est la seule étape où la machine décore au lieu de découper.

1. Décorer les planches. Gravure laser par petits groupes, feutres et pochoirs pour le reste. Les planches sont prédécoupées et pré-percées en amont : la séance sert à s’approprier l’objet, pas à faire la découpe.
2. Monter la caisse. Assemblage des faces à la visserie, serre-joints et main d’adulte, vérification de l’équerrage, ponçage léger. On marque l’emplacement de la caméra à ce moment-là, avant de refermer.
3. Installer l’électronique. Boîtier imprimé, passage et protection des câbles, test de l’image, puis étanchéité autour de l’objectif. Tous les raccords se font au bornier ou au Wago : aucune soudure, c’est ce qui permet aux enfants de câbler eux-mêmes.
4. Poser le nichoir. Fixation sur l’arbre entre 2 et 5 m du sol par un adulte, essai de l’image en conditions réelles, puis consignes d’observation.

Fabriqué avec les enfants du centre social de La Brunetière, à l’Atelier Partagé (La Traverse, Bergerac), en août 2025.

Fichiers et plans

• Plan du nichoir - les cotes des faces, du toit en deux parties et du trou d’envol, dimensionné pour la mésange charbonnière.
• Fichier de gravure au format xTool, pour la personnalisation des planches.
• Boîtier ESP32-CAM-MB et cache USB-A, deux pièces imprimées en PLA.
• Liste de matériel - la version détaillée, avec les références des modules d’alimentation.
• Le programme, un sketch Arduino d’une centaine de lignes : point d’accès ouvert, page d’accueil, capture JPEG sur /jpg, flux MJPEG sur /stream. Il appelle un logo_small.h qui n’est pas fourni (le logo du nichoir converti en tableau d’octets). Sans lui, retirer l’#include et la route /logo.png.

Le programme bascule tout seul en résolution réduite si la carte n’a pas de mémoire PSRAM ; utile, parce que les ESP32-CAM du commerce ne se valent pas d’un lot à l’autre.

Le programme complet (C++)

// Nichoir connecté avec une ESP32-CAM-MB + CAM IR + LED IR + Condensateur 1kµF
 
#include "esp_camera.h"
#include <WiFi.h>
#include "esp_wifi.h"
#include <WebServer.h>
#include "logo_small.h" // <-- Logo optimisé intégré
 
// Carte : ESP32 -> AI Thinker ESP32-CAM - Faire un premier flashage avec le bouton RST pendant la compilation
// Atelier Partagé @La Traverse
 
// ==== Config AP (ouvert) ====
const char* ssid_ap   = "Nichoir";
const int   canal_ap  = 1; // Canal WiFi
 
// ==== LED flash ====
const int broche_led_flash = 4;
 
// ==== Caméra (AI Thinker) ====
static camera_config_t cfg_cam = {
  .pin_pwdn  = 32, .pin_reset = -1, .pin_xclk = 0,
  .pin_sscb_sda = 26, .pin_sscb_scl = 27,
  .pin_d7 = 35, .pin_d6 = 34, .pin_d5 = 39, .pin_d4 = 36,
  .pin_d3 = 21, .pin_d2 = 19, .pin_d1 = 18, .pin_d0 = 5,
  .pin_vsync = 25, .pin_href  = 23, .pin_pclk  = 22,
  .xclk_freq_hz = 20000000,
  .ledc_timer   = LEDC_TIMER_0, .ledc_channel = LEDC_CHANNEL_0,
  .pixel_format = PIXFORMAT_JPEG,
  .frame_size   = FRAMESIZE_VGA,
  .jpeg_quality = 12,
  .fb_count     = 2
};
 
WebServer serveur(80);
 
String ipToStr(IPAddress ip){ return String(ip[0])+"."+String(ip[1])+"."+String(ip[2])+"."+String(ip[3]); }
 
// ===== Route pour envoyer le logo PNG =====
void envoyerLogo() {
  serveur.send_P(200, "image/png", (const char*)logo, logo_len);
}
 
// ===== Page d'accueil =====
void pageAccueil() {
  String html;
  html.reserve(3000);
  html += F(
    "<!doctype html><html lang='fr'><head><meta charset='utf-8'>"
    "<meta name='viewport' content='width=device-width,initial-scale=1'>"
    "<title>Nichoir connecté</title>"
    "<style>"
      "body{font-family:sans-serif;margin:0;padding:24px;background:#0b1020;color:#f5f7ff;}"
      ".carte{max-width:760px;margin:0 auto;background:#111735;border:1px solid #263156;"
      "border-radius:16px;box-shadow:0 6px 24px rgba(0,0,0,.35);padding:20px;}"
      "h1{font-size:1.35rem;margin:0 0 8px 0;font-weight:700;text-align:center;}"
      ".liens{display:grid;gap:10px;margin-top:12px}"
      "a{background:#1f2a52;border:1px solid #2d3a6f;color:#e8edff;padding:10px 14px;border-radius:10px;text-decoration:none}"
      "a:hover{background:#263062}"
      ".meta{margin-top:12px;font-size:.9rem;color:#c9d3ff;text-align:center;}"
      "img{max-width:200px;display:block;margin:10px auto;}"
    "</style></head><body>"
    "<div class='carte'>"
  );
  html += F("<h1>Bienvenue sur le nichoir connecté de La Brunetière</h1>");
  html += "<img src='/logo.png' alt='Logo du nichoir'>";
  html += F("<div class='liens'>"
              "<a href='/stream'>🎥 Flux vidéo (MJPEG)</a>"
              "<a href='/jpg'>📷 Photo instantanée (JPEG)</a>"
            "</div>");
  html += F("<div class='meta'>IP locale : <code id='host'></code></div>"
            "<script>document.getElementById('host').textContent=location.origin;</script>");
  html += F("</div></body></html>");
  serveur.send(200, "text/html; charset=utf-8", html);
}
 
// ===== Capture JPEG =====
void captureJPEG() {
  camera_fb_t *fb = esp_camera_fb_get();
  if(!fb){ serveur.send(500,"text/plain; charset=utf-8","Erreur capture"); return; }
  serveur.setContentLength(fb->len);
  serveur.send(200,"image/jpeg");
  serveur.client().write(fb->buf, fb->len);
  esp_camera_fb_return(fb);
}
 
// ===== Flux MJPEG =====
void fluxMJPEG() {
  WiFiClient c = serveur.client();
  c.print("HTTP/1.1 200 OK\r\n"
          "Cache-Control: no-cache\r\nPragma: no-cache\r\n"
          "Content-Type: multipart/x-mixed-replace; boundary=frame\r\n\r\n");
  while(c.connected()){
    camera_fb_t *fb = esp_camera_fb_get();
    if(!fb) break;
    c.print("--frame\r\nContent-Type: image/jpeg\r\nContent-Length: ");
    c.print(fb->len); c.print("\r\n\r\n"); c.write(fb->buf, fb->len); c.print("\r\n");
    esp_camera_fb_return(fb);
    delay(30);
  }
}
 
// ===== SETUP =====
void setup(){
  pinMode(broche_led_flash, OUTPUT);
  digitalWrite(broche_led_flash, LOW);
 
  Serial.begin(115200); delay(200);
 
  WiFi.mode(WIFI_AP);
  WiFi.persistent(false);
  WiFi.setSleep(false);
  wifi_country_t wc = {"FR", 1, 13, 0, WIFI_COUNTRY_POLICY_MANUAL};
  esp_wifi_set_country(&wc);
 
  if(!WiFi.softAP(ssid_ap, NULL, canal_ap, 0, 4)){
    Serial.println("Echec AP");
    while(true){ delay(1000); }
  }
  Serial.print("AP OK, SSID: "); Serial.println(ssid_ap);
  Serial.print("IP AP: "); Serial.println(ipToStr(WiFi.softAPIP()));
 
  if(!psramFound()){
    cfg_cam.frame_size   = FRAMESIZE_QVGA;
    cfg_cam.jpeg_quality = 15;
    cfg_cam.fb_count     = 1;
  }
  if(esp_camera_init(&cfg_cam)!=ESP_OK){
    Serial.println("Echec init camera");
  }
 
  serveur.on("/", pageAccueil);
  serveur.on("/jpg", HTTP_GET, captureJPEG);
  serveur.on("/stream", HTTP_GET, fluxMJPEG);
  serveur.on("/logo.png", envoyerLogo);
 
  serveur.begin();
}
 
void loop(){ serveur.handleClient(); }

Ce qu’on ferait autrement

Le sujet du projet, c’est l’alimentation, pas la caméra. On croit fabriquer un objet vidéo, on passe le temps sur la chute de tension dans un câble. À refaire, choisir la section du câble d’abord et les convertisseurs ensuite, plutôt que l’inverse.

Faire le premier flashage avant la séance. La carte ne se programme la première fois qu’en maintenant le bouton RST pendant la compilation. C’est un piège classique, sans rapport avec le projet, et il coûte vingt minutes devant un groupe d’enfants qui attend.

Tester le module caméra la veille, et en avoir un deuxième. Un module mort en séance 3, c’est la séance perdue et le nichoir qui part sans son intérêt.

L’étanchéité mérite mieux qu’un joint de colle chaude. C’est ce qui a été fait, et ça tient une saison au mieux. Un vrai passe-câble et une petite casquette au-dessus de l’objectif seraient à dessiner dès la conception, pas à rattraper en fin de montage.

Ce projet a été soutenu en 2025 par la Fondation Afnic, financée par le .fr, et la Fondation groupe EDF.